gemtext-document      = 1*gemtext-line
gemtext-line          =  text-line / link-line / heading-line / list-line
gemtext-line          =/ quote-line / preformat-toggle-line
link-line             = "=>" SP URI-reference [SP 1*(VCHAR / SP)] CRLF
heading-line          = 1*4"#" SP text-line
list-line             = "*" SP text-line
quote-line            = ">" SP text-line
preformat-toggle-line = "```" text-line
text-line             = *(VCHAR / SP) CRLF

; https://www.rfc-editor.org/rfc/rfc5234
ALPHA          =  %x41-5A / %x61-7A   ; A-Z / a-z

BIT            =  "0" / "1"

CHAR           =  %x01-7F
                               ; any 7-bit US-ASCII character,
                               ;  excluding NUL
CR             =  %x0D
                               ; carriage return

CRLF           =  CR LF
                               ; Internet standard newline

CTL            =  %x00-1F / %x7F
                               ; controls

DIGIT          =  %x30-39
                               ; 0-9

DQUOTE         =  %x22
                               ; " (Double Quote)

HEXDIG         =  DIGIT / "A" / "B" / "C" / "D" / "E" / "F"

HTAB           =  %x09
                               ; horizontal tab

LF             =  %x0A
                               ; linefeed

LWSP           =  *(WSP / CRLF WSP)
                               ; Use of this linear-white-space rule
                               ;  permits lines containing only white
                               ;  space that are no longer legal in
                               ;  mail headers and have caused
                               ;  interoperability problems in other
                               ;  contexts.
                               ; Do not use when defining mail
                               ;  headers and use with caution in
                               ;  other contexts.

OCTET          =  %x00-FF
                               ; 8 bits of data

SP             =  %x20

VCHAR          =  %x21-7E
                               ; visible (printing) characters

WSP            =  SP / HTAB
                               ; white space



; https://www.rfc-editor.org/rfc/rfc3986
pct-encoded = "%" HEXDIG HEXDIG

reserved    = gen-delims / sub-delims

gen-delims  = ":" / "/" / "?" / "#" / "[" / "]" / "@"

sub-delims  = "!" / "$" / "&" / "'" / "(" / ")"
                 / "*" / "+" / "," / ";" / "="

unreserved  = ALPHA / DIGIT / "-" / "." / "_" / "~"
URI         = scheme ":" hier-part [ "?" query ] [ "#" fragment ]

hier-part   = "//" authority path-abempty
                 / path-absolute
                 / path-rootless
                 / path-empty

scheme      = ALPHA *( ALPHA / DIGIT / "+" / "-" / "." )

authority   = [ userinfo "@" ] host [ ":" port ]

userinfo    = *( unreserved / pct-encoded / sub-delims / ":" )

host        = IP-literal / IPv4address / reg-name

IP-literal = "[" ( IPv6address / IPvFuture  ) "]"

IPvFuture  = "v" 1*HEXDIG "." 1*( unreserved / sub-delims / ":" )

IPv6address =                            6( h16 ":" ) ls32
                 /                       "::" 5( h16 ":" ) ls32
                 / [               h16 ] "::" 4( h16 ":" ) ls32
                 / [ *1( h16 ":" ) h16 ] "::" 3( h16 ":" ) ls32
                 / [ *2( h16 ":" ) h16 ] "::" 2( h16 ":" ) ls32
                 / [ *3( h16 ":" ) h16 ] "::"    h16 ":"   ls32
                 / [ *4( h16 ":" ) h16 ] "::"              ls32
                 / [ *5( h16 ":" ) h16 ] "::"              h16
                 / [ *6( h16 ":" ) h16 ] "::"

ls32        = ( h16 ":" h16 ) / IPv4address
                 ; least-significant 32 bits of address

h16         = 1*4HEXDIG
                 ; 16 bits of address represented in hexadecimal

IPv4address = dec-octet "." dec-octet "." dec-octet "." dec-octet

dec-octet   = DIGIT                 ; 0-9
                 / %x31-39 DIGIT         ; 10-99
                 / "1" 2DIGIT            ; 100-199
                 / "2" %x30-34 DIGIT     ; 200-249
                 / "25" %x30-35          ; 250-255

reg-name    = *( unreserved / pct-encoded / sub-delims )

port        = *DIGIT

path          = path-abempty    ; begins with "/" or is empty
                   / path-absolute   ; begins with "/" but not "//"
                   / path-noscheme   ; begins with a non-colon segment
                   / path-rootless   ; begins with a segment
                   / path-empty      ; zero characters

path-abempty  = *( "/" segment )
path-absolute = "/" [ segment-nz *( "/" segment ) ]
path-noscheme = segment-nz-nc *( "/" segment )
path-rootless = segment-nz *( "/" segment )
path-empty    = 0<pchar>
segment       = *pchar
segment-nz    = 1*pchar
segment-nz-nc = 1*( unreserved / pct-encoded / sub-delims / "@" )
                   ; non-zero-length segment without any colon ":"

pchar         = unreserved / pct-encoded / sub-delims / ":" / "@"

query       = *( pchar / "/" / "?" )

fragment    = *( pchar / "/" / "?" )

URI-reference = URI / relative-ref
relative-ref  = relative-part [ "?" query ] [ "#" fragment ]

relative-part = "//" authority path-abempty
                   / path-absolute
                   / path-noscheme
                   / path-empty

absolute-URI  = scheme ":" hier-part [ "?" query ]
<!DOCTYPE html><html><head><meta charset="utf-8" /><meta name="viewport" content="width=device-width, initial-scale=1.0"><link rel="canonical" href="gemini://michaelnordmeyer.com/files/2024-04-14-on-gemtext-specification-0-24-0-proposal.txt" /><title>gemini://michaelnordmeyer.com/files/2024-04-14-on-gemtext-specification-0-24-0-proposal.txt</title><style>.c{max-width:80em;margin-left:auto;margin-right:auto;}.l{margin:0;color:lightgray;}.m{margin-top:0;margin-bottom:0;}.b{display:list-item;list-style-type:disc;list-style-position:inside;}</style></head><body><p class="l">-- Leo's gemini proxy</p><p class="l">-- Connecting to michaelnordmeyer.com:1965...</p><p class="l">-- Connected</p><p class="l">-- Sending request</p><p class="l">-- Meta line: 20 text/plain;lang=en-US</p><p class="l">-- Response ended</p><p class="l">-- Page fetched on Sun May 19 08:50:18 2024</p></body></html>